Using italic, bold, upper, lower letter and degree charactor ° with gnuplot

gnuplot 4.x でのイタリック、ボールド、上付き、下付き文字及び度記号 ° の使用例　V_f–I_f 特性例, postscript 出力）

#!/gnuplot
set encoding iso_8859_1
k = 1.380649e-023
q = 1.602176634e-019
If(Vf, T, Is, n) = Is * (exp(q * Vf / (n * k * (T + 273.15))) - 1)
set key spacing 1.5
set xlabel "{/Helvetica-Oblique V}_{f} [V]"
set ylabel "{/Helvetica-Oblique I}_{f} [{/Symbol m}A]"
set title "{/Helvetica-Oblique I}_{f} {\055} {/Helvetica-Oblique V}_{f} ({/Helvetica-Oblique T}_{j} = 25 \260C)"
set xrange[0:0.1]
set xtics 0.01
set logscale y
set yrange[0.01:10]
set ytics add (0.02, 0.05, 0.2, 0.5, 2, 5)
set label 1 "{/Helvetica-Bold Shockley diode equation} : {/Times-Oblique I}_{f} = \
{/Times-Oblique I}_{s} ({/Times-Roman e}^{{/Times-Oblique q}{/Times-Oblique V}_{f} \
/ ({/Times-Oblique n k T})} - {/Times-Roman 1})" at 0.045, 0.03
set terminal postscript solid color enhanced
set output "vf-if.ps"
plot 1e6 * If(x, 25, 4.6e-8, 1.09) t "HSMS-8201", 1e6 * If(x, 25, 2.94707e-08, 1.36601) t "MMBD301&{kk}"
set output

Freqently used symbols:

α : {/Symbol a}

β : {/Symbol b}

γ : {/Symbol g}

δ : {/Symbol d}

Δ : {/Symbol D}

ε : {/Symbol-Oblique e}

η : {/Symbol-Oblique h}

θ : {/Symbol-Oblique q}

λ : {/Symbol-Oblique l}

μ : {/Symbol m}

ω : {/Symbol-Oblique o}

π : {Symbol p}

σ : {/Symbol s}

Ω : {/Symbol W}

Φ : {/Symbol-Oblique P}

ζ : {Symbol z}

χ : {Symbol c}

≤ : {/Symbol \243}

∞ : {/Symbol \245}

≥ : {/Symbol \263}

≠ : {/Symbol \271}

≈ : {/Symbol \273}

↔ : {/Symbol \253}

← : {/Symbol \254}

↑ : {/Symbol \255}

→ : {/Symbol \256}

↓ : {/Symbol \257}

° : \260

± : {/Symbol \261}

× : {/Symbol \264}

√ : {/Symbol \326}

Note: gnuplot 内部で扱える値の範囲は ±1.7976931348623158E+308 だけど print 出来る範囲は ±8.98846567431158E+307