Impedance to S-parameter conversion

for the HP 42S
Z→S₁₁ - Impedance to Scattering parameter conversion

Usage

[XEQ] [Z→S]

Input

MEM "Z.r"  : Impedance (real part)     [Ω]
MEM "Z.i"  : Impedance (imaginal part) [Ω]
MEM "Z0"   : Characteristic Impedance  [Ω]

Resources used

MEM "S11"  : S₁₁ - the complex one port reflection coefficient Γ
MEM  00    : "Inf. " Infinity
MEM  11    : |S₁₁| - S₁₁ magnitude

Output

REG t      : Z    - the complex impedance
MEM z      : RL   - return loss [dB]
MEM y      : VSWR - voltage standing wave ratio
REG X      : S₁₁  - the complex one port reflection coefficient

Program list (Rev.1.10 Oct. 9, 2010)

Impedance → S₁₁ conversion

00 { 150-Byte Prgm }
01 LBL "Z→S"
02 MVAR "Z.r" 
03 MVAR "Z.i"
04 MVAR "Z0"
05 VARMENU "Z→S"
06 STOP
07 EXITALL
08 "Inf. "
09 ASTO 00
10 DEG
11 RECT
12 RCL "Z.r"
13 RCL "Z.i"
14 COMPLEX           ; Z = Z.r + j Z.i
15 ENTER
16 RCL- "Z0"
17 LASTX 
18 RCL+ "Z0"
19 ÷
20 STO "S11"         ; S₁₁ = Γ = (Z - Z₀) / (Z + Z₀)
21 POLAR
22 FIX 04
23 "S11="
24 ARCL ST X 
25 ABS
26 STO 11            ; |Γ|
27 "^L_FRL="
28 X>0?
29 GTO 01
30 ARCL 00           ; RL = ∞
31 GTO 02
32 LBL 01
33 LOG
34 20
35 ×                 ; RL = 20log₁₀|S₁₁|
36 FIX 02
37 ARCL ST X
38 "dB "
39 LBL 02
40 "SWR="
41 1
42 RCL+ 11
43 1
44 RCL- 11
45 X≠0?
46 GTO 11
47 ARCL 00           ; VSWR = ∞
48 GTO 12
49 LBL 11
50 ÷                 ; VSWR = (1 + |Γ|) / (1 - |Γ|)
51 ARCL ST X
52 LBL 12
53 AVIEW
54 RCL "S11"
55 RECT
56 RAD
57 ENG 10
58 RTN
59 .END.

Example

Input	Impedance plot on the smith chart
`Z.r = 70 Z.i = -30 Z0 = 50`
Output
`t: 70.0E0 -i30.0E0 z: -10.707480785E0 y: 1.8228315177E0 x: 216.E-3 -i196.E-3`