BPFMF - Multiple feedback Band-Pass-Filter / HP-42S

for the HP 42S
BPFMF - Calculate voltage gain, center frequency and Q of a multiple-feedback band-pass-filter.

Multiple feedback band-pass-filter

Input

Var R1: Resistance [Ω]
Var R2: Resistance [Ω]
Var R3: Resistance [Ω]
Var C1: Capacitance [F]
Var C2: Capacitance [F]

Resources to be used

REG 00: ω ‐ natural angular frequency


Output


Var h: h ‐ Gain coefficient
Var Q: Q ‐ Quality factor
Var f: f_c ‐ Center frequency [Hz]
REG z: h ‐ Gain coefficient
REG y: Q ‐ Quality factor
REG x: f_c ‐ Center frequency [Hz]



Program list


BPFMF - Rev.1.00 : Aug. 1 2011



00 { 178-Byte Prgm }
01 LBL "BPFMF"
02 MVAR "R1"
03 MVAR "R2"
04 MVAR "R3"
05 MVAR "C1"
06 MVAR "C2"
07 VARMENU "BPFMF"
08 STOP
09 EXITALL
10 RCL "R1"
11 RCL+ "R2"
12 RCL "R1"
13 RCL× "R2"
14 ÷
15 ENTER
16 RCL× "R3"
17 RCL "C1"
18 RCL× "C2"
19 ×
20 SQRT
21 RCL "C1"
22 RCL+ "C2"
23 ÷
24 STO "Q"
25 X<>Y
26 RCL "C1"
27 RCL× "C2"
28 RCL× "R3"
29 ÷
30 SQRT
31 STO 00
32 2
33 PI
34 ×
35 ÷
36 STO "f"
37 RCL "C2"
38 ENTER
39 RCL+ "C1"
40 RCL× "R1"
41 ÷
42 RCL× "R3"
43 STO "h"
44 RCL "Q"
45 RCL "f"
46 CLA
47 ENG 03
48 "h="
49 ARCL "h"
50 ", Q="
51 ARCL "Q"
52 "^L_FFc="
53 ARCL "f"
54 " [Hz] BPFMF"
55 AVIEW
56 ENG 10
57 RTN
58 .END.








Example


Input
R1 = 4.3e3
R2 = 402
R3 = 43e3
C1 = 1e-9
C2 = 1e-9

Output
z: 5.0000000000E0
y: 5.4075219401E0
x: 40.029481239E3








Download 'BPFMF-1.0'
(bpfmf.raw, 181 byte, raw program file for the
 Free42)







© 2000 Takayuki HOSODA.


Powered by